Reassign AGC file extension to assembly files

Luminary099/RADAR_LEADIN_ROUTINES.agc

@@ -0,0 +1,103 @@
+# Copyright:	Public domain.
+# Filename:	RADAR_LEADIN_ROUTINES.agc
+# Purpose: 	Part of the source code for Luminary 1A build 099.
+#		It is part of the source code for the Lunar Module's (LM)
+#		Apollo Guidance Computer (AGC), for Apollo 11.
+# Assembler:	yaYUL
+# Contact:	Ron Burkey <info@sandroid.org>.
+# Website:	www.ibiblio.org/apollo.
+# Pages:	490-491
+# Mod history:	2009-05-17 RSB	Adapted from the corresponding 
+#				Luminary131 file, using page 
+#				images from Luminary 1A.
+#
+# This source code has been transcribed or otherwise adapted from
+# digitized images of a hardcopy from the MIT Museum.  The digitization
+# was performed by Paul Fjeld, and arranged for by Deborah Douglas of
+# the Museum.  Many thanks to both.  The images (with suitable reduction
+# in storage size and consequent reduction in image quality as well) are
+# available online at www.ibiblio.org/apollo.  If for some reason you
+# find that the images are illegible, contact me at info@sandroid.org
+# about getting access to the (much) higher-quality images which Paul
+# actually created.
+#
+# Notations on the hardcopy document read, in part:
+#
+#	Assemble revision 001 of AGC program LMY99 by NASA 2021112-61
+#	16:27 JULY 14, 1969 
+
+# Page 490
+		BANK	25
+		SETLOC	RRLEADIN
+		BANK
+		
+		EBANK=	RSTACK
+		
+# RADAR SAMPLING LOOP.
+
+		COUNT*	$$/RLEAD
+RADSAMP		CCS	RSAMPDT		# TIMES NORMAL ONCE PER SECOND SAMLING
+		TCF	+2
+		TCF	TASKOVER	# +0 INSERTED MANUALLY TERMINATES TEST.
+		
+		TC	WAITLIST
+		EBANK=	RSTACK
+		2CADR	RADSAMP
+		
+		CAF	PRIO25
+		TC	NOVAC
+		EBANK=	RSTACK
+		2CADR	DORSAMP
+		
+		CAF	BIT14		# FOR CYCLIC SAMPLING, RTSTDEX=
+		EXTEND			# RTSTLOC/2 + RTSTBASE
+		MP	RTSTLOC
+		AD	RTSTBASE	# 0 FOR RR, 2 FOR LR.
+		TS	RTSTDEX
+		TCF	TASKOVER
+		
+# DO THE ACTUAL RADAR SAMPLE.
+
+DORSAMP		TC	VARADAR		# SELECTS VARIABLE RADAR CHANNEL.
+		TC	BANKCALL
+		CADR	RADSTALL
+		
+		INCR	RFAILCNT	# ADVANCE FAIL COUNTER BUT ACCEPT BAD DATA
+		
+DORSAMP2	INHINT
+		CA	FLAGWRD5	# DON'T UPDATE RSTACK IF IN R77.
+		MASK	R77FLBIT
+		CCS	A
+		TCF	+4
+		
+		DXCH	SAMPLSUM
+		INDEX	RTSTLOC
+		DXCH	RSTACK
+		
+		CS	RTSTLOC		# CYCLE RTSTLOC.
+		AD	RTSTMAX
+		EXTEND
+		
+# Page 491		
+		BZF	+3
+		CA	RTSTLOC
+		AD	TWO		# STORAGE IS DP
+		TS	RTSTLOC
+		TCF	ENDOFJOB	# CONTINUOUS SAMPLING AND 2N TRIES -- GONE.
+		
+# VARIABLE RADAR DATA CALLER FOR ONE MEASUREMENT ONLY.
+
+VARADAR		CAF	ONE		# WILL BE SENT TO RADAR ROUTINE IN A BY
+		TS	BUF2		# SWCALL
+		INDEX	RTSTDEX
+		CAF	RDRLOCS
+		TCF	SWCALL		# NOT TOUCHING Q.
+		
+RDRLOCS		CADR	RRRANGE		# = 0
+		CADR	RRRDOT		# = 1
+		CADR	LRVELX		# = 2
+		CADR	LRVELY		# = 3
+		CADR	LRVELZ		# = 4
+		CADR	LRALT		# = 5
+		
+